{ config, pkgs, lib, inputs, ... }:
{
  nixpkgs.overlays = [
    (final: _: {
      unstable = import inputs.nixpkgs-unstable {
        inherit (final.stdenv.hostPlatform) system;
        inherit (final) config;
      };
    })

    # test phase taking too long
    (final: prev: {
      openblas = prev.openblas.overrideAttrs (
        finalAttrs: prevAttrs: {
          doCheck = false;
          dontCheck = true;
          passthru.tests = {};
        }
      );
    })

    # reverting version to 0.16.1 due to bug with IME
    (final: prev: {
      alacritty = prev.alacritty.overrideAttrs (
        finalAttrs: prevAttrs: {
          version = "0.16.1";
          src = prev.fetchFromGitHub {
            owner = "ayosec";
            repo = "alacritty";
            tag = "v${finalAttrs.version}-graphics";
            hash = "sha256-e+o0GLy05qXEY4T57dCuqhukTKBSm1WIHzPUV8uswRI=";
          };
          cargoDeps = prev.rustPlatform.fetchCargoVendor {
            inherit (finalAttrs) src;
            hash = "sha256-VR+URXqsB9zCOSow/f/aWXUlrp6j2XeK0zKESQGzMek=";
          };
        }
      );
    })

    inputs.my-ricing-assets.overlays.x86_64-linux.default
  ];
}