set output "exp1-bode.tex"
set encoding utf8
set terminal epslatex color font "Arial,12" fontscale 1.0 size 10.5cm,7.5cm
set style data lines
set style line 1 linetype 1 linewidth 1 linecolor rgb "red"
set style line 2 linetype 1 linewidth 1 linecolor rgb "blue"
set style line 91 linetype 1 linewidth 1 linecolor rgb "black"
set style line 92 linetype 1 linewidth 0.5 linecolor rgb "gray20"
set style line 93 linetype 1 linewidth 0.5 linecolor rgb "gray60"

set border ls 91
set tic scale 0.8,0.5
set grid xtics,mxtics ls 92, ls 93
set grid ytics,mytics ls 92, ls 93

set key left top

set log x
set xrange [1e2:1.2e6]

set multiplot layout 2,1 rowsfirst

set xlabel 
set ylabel "Gain (dB)"
set format x ""

plot "exp1-data-unadjusted.txt" u 1:2 title "Unadjusted" with points pt '*', "exp1-data-adjusted.txt" u 1:2 title "Adjusted" with points pt 'x'

unset key
set xtics add ("1k" 1e3, "3k" 3e3, "10k" 1e4, "30k" 3e4, "100k" 1e5, "300k" 3e5, "1M" 1e6)
set xlabel "Frequency (Hz)"
set ylabel "Phase (deg)"

plot "exp1-data-unadjusted.txt" u 1:3 title "Unadjusted" with points pt '*', "exp1-data-adjusted.txt" u 1:3 title "Adjusted" with points pt 'x'

unset multiplot
